blob: 8c2efe2f2ffdd6596941c3aaa255289a8138dd6b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
# Maintainer of the mpv package: Christian Hesse <mail@eworm.de>
# Contributor to the mpv package: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor to the mpv package: Eivind Uggedal <eivind@uggedal.com>
_pkgname=mpv
pkgname=mpv-nowayland
epoch=1
pkgver=0.14.0
pkgrel=1
pkgdesc='Video player based on MPlayer/mplayer2'
arch=('i686' 'x86_64')
license=('GPL')
url='http://mpv.io'
depends=(
'ffmpeg' 'lcms2' 'libcdio-paranoia' 'libgl' 'enca' 'libxss'
'libxinerama' 'libxv' 'libxkbcommon' 'libva' 'libcaca'
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils' 'lua52' 'libdvdnav'
'libguess' 'libxrandr' 'jack' 'smbclient' 'rubberband'
)
makedepends=('mesa' 'python-docutils' 'ladspa' 'hardening-wrapper')
optdepends=('youtube-dl: for video-sharing websites playback')
options=('!emptydirs' '!buildflags')
conflicts=("$_pkgname")
provides=("$_pkgname=$pkgver")
install=mpv.install
source=("$_pkgname-$pkgver.tar.gz::https://github.com/mpv-player/$_pkgname/archive/v$pkgver.tar.gz")
sha256sums=('042937f483603f0c3d1dec11e8f0045e8c27f19eee46ea64d81a3cdf01e51233')
prepare() {
cd ${_pkgname}-${pkgver}
./bootstrap.py
}
build() {
cd ${_pkgname}-${pkgver}
./waf configure --prefix=/usr \
--confdir=/etc/mpv \
--enable-zsh-comp \
--enable-libmpv-shared \
--enable-cdda \
--disable-wayland \
--disable-gl-wayland
./waf build
}
package() {
cd ${_pkgname}-${pkgver}
./waf install --destdir="$pkgdir"
install -m644 DOCS/{encoding.rst,tech-overview.txt} \
"$pkgdir"/usr/share/doc/mpv
}
|
