path: root/sysvinit/PKGBUILD

# Maintainer: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
pkgname=sysvinit
pkgver=2.88
pkgrel=11
pkgdesc='Linux System V Init'
url='http://savannah.nongnu.org/projects/sysvinit'
arch=('i686' 'x86_64')
license=('GPL')
depends=('sysvinit-tools')

source=("http://download.savannah.gnu.org/releases/sysvinit/sysvinit-${pkgver}dsf.tar.bz2"
        "0001-simplify-writelog.patch" "0002-remove-ansi-escape-codes-from-log-file.patch")
sha256sums=('60bbc8c1e1792056e23761d22960b30bb13eccc2cabff8c7310a01f4d5df1519'
            '8126d09a35bdb9137bb19dc31b58cf1e829137fba34f7dcde7598018e1736826'
            '90d38e4351ef9d77088661b411eb2b20eda435676e1e407f3d959ca2064d5c1e')


build()
{
    cd "$srcdir/$pkgname-${pkgver}dsf"
    patch -p1 -d "src" -i "$srcdir/0001-simplify-writelog.patch"
    patch -p1 -d "src" -i "$srcdir/0002-remove-ansi-escape-codes-from-log-file.patch"
    make
}

package()
{
    cd "$srcdir/$pkgname-${pkgver}dsf"
    mkdir -p "$pkgdir/__temp__"
    make ROOT="$pkgdir/__temp__" install
    cd "$pkgdir/__temp__"
    rm "bin/pidof"
    ln -s "../sbin/killall5" "bin/pidof"
    rm -r bin sbin/{sulogin,bootlogd,fstab-decode,killall5} usr/bin \
          usr/share/man/man?/{mesg,mountpoint,pidof,sulogin,utmpdump,wall,last,lastb,bootlogd,fstab-decode,killall5}.?
    find . | while read file; do
        if [ -d "$file" ]; then
            mkdir -p ".$file"
        else
            cp "$file" ".$file"
        fi
    done
    cd ..
    rm -r "__temp__"
    mv "$pkgdir/sbin" "$pkgdir/usr/bin"
}