path: root/emacs-gtk2/PKGBUILD

#Maintainer: Mattias Andrée <maandree@operamail.com>
#Official Arch Linux package repository [gtk3 version] maintainer: Juergen Hoetzel <juergen@archlinux.org>
#Official Arch Linux package repository [gtk3 version] contributor: Renchi Raju <renchi@green.tam.uiuc.edu>

_pkgname=emacs
pkgname=$_pkgname-gtk2
pkgver=24.3
pkgrel=1
pkgdesc="The extensible, customizable, self-documenting real-time display editor. GTK2 version"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/emacs/emacs.html"
license=('GPL3')
depends=('librsvg' 'gpm' 'giflib' 'libxpm' 'libotf' 'm17n-lib' 'gtk2' 'hicolor-icon-theme' 'gconf' 'desktop-file-utils' 'alsa-lib' 'imagemagick')
install=emacs-gtk2.install
source=(ftp://ftp.gnu.org/gnu/emacs/$_pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('70aa2942e9ae689ed17eddedfca5027c364ffbcc8b59968b1645e935f4c7058d' '6c258b159c921006eee4b1a1aeb1be75a79ad8ed92b36b1b08b262d41a091093')
provides=('emacs')
conflicts=('emacs')


build() {
  cd "$srcdir"/emacs-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib \
    --localstatedir=/var --with-x-toolkit=gtk2 --with-xft
  make
}

package() {
  cd "$srcdir"/$_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  
  # remove conflict with ctags package
  mv "$pkgdir"/usr/bin/{ctags,ctags.emacs}
  mv "$pkgdir"/usr/share/man/man1/{ctags.1.gz,ctags.emacs.1}

  # fix user/root permissions on usr/share files
  find "$pkgdir"/usr/share/emacs/$pkgver -exec chown root:root {} \;
  
  # fix perms on /var/games
  chmod 775 "$pkgdir"/var/games
  chmod 775 "$pkgdir"/var/games/emacs
  chmod 664 "$pkgdir"/var/games/emacs/*
  chown -R root:games "$pkgdir"/var/games
}