path: root/dist/archlinux/stable/PKGBUILD

# Maintainer: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>

pkgname=general-preprocessor
pkgver=1.1.1
pkgrel=1
pkgdesc="Bash based preprocessor for anything"
url="https://github.com/maandree/gpp"
arch=(any)
license=(GPL3)
depends=(python bash)
makedepends=(make coreutils python texinfo)
install=general-preprocessor.install
source=("${url}/archive/${pkgver}.tar.gz")
sha256sums=(46e03434dc00cf292ed14188d7baf771f59ae325f98f88df571c07e5f68b2cfa)

_prefix=/usr
_command=gpp ## change this if you have a package conflicting package


build() {
        cd "${srcdir}/gpp-${pkgver}"
        make PREFIX="${_prefix}" PKGNAME="${pkgname}" COMMAND="${_command}" DESTDIR="${pkgdir}"
}

package() {
        cd "${srcdir}/gpp-${pkgver}"
        make PREFIX="${_prefix}" PKGNAME="${pkgname}" COMMAND="${_command}" DESTDIR="${pkgdir}" install
        _dir="${pkgdir}${_prefix}/share/licenses/${pkgname}"
        ln -sf -- "/usr/share/licenses/common/GPL3" "${_dir}/LICENSE"
}