# Maintainer: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
pkgname=dooble
pkgver=1.43
pkgrel=1
pkgdesc='A safe WebKit Web browser'
url='http://dooble.sourceforge.net/'
arch=('i386' 'x86_64')
license=('GPL2')
depends=('bzip2' 'fontconfig' 'gstreamer0.10-base' 'libgcrypt' 'libjpeg'
         'libsm' 'libxrender' 'mesa-libgl' 'openssl' 'qtwebkit' 'udev' 'xz')
# Transversally included dependencies:  glibc expat freetype2 pcre libffi glib2 libxml2 orc gstreamer0.10 zlib util-linux-ng
#                                       libice libxcb libx11 libxfixes libxext libxdamage libdrm mesa libpng sqlite gcc-libs
#                                       libxau libxdmcp libxxf86vm qt4 libgpg-error
source=('http://downloads.sourceforge.net/project/dooble/Version%201.43/Dooble.d.tar.gz?r=&ts=1375742462&use_mirror=garr')
sha256sums=(6b8bcc2d5c520796f6acaed09b874beaba7a693f07670149fb67a4f02c23722d)
options=('!emptydirs')


build()
{
    cd "$srcdir/dooble.d/trunk/browser/"
    sed -i 's_-Werror__g' dooble.pro
    qmake-qt4 -o Makefile dooble.pro
    make
}

package()
{
    cd "$srcdir/dooble.d/trunk/browser/"
    make INSTALL_ROOT="$pkgdir" install
    
    msg "Fixing file structure"
    mkdir "$pkgdir/opt"
    mv "$pkgdir/usr/local/dooble" "$pkgdir/opt"
    mv "$pkgdir/usr/local/include" "$pkgdir/usr"
    rmdir "$pkgdir/usr/local/" || echo "Cannot remove \$pkgdir/usr/local/"
    
    msg "Editing files for the file structure modification"
    sed -i s_'/usr/local/dooble'_'/opt/dooble'_g "$pkgdir/opt/dooble/dooble.sh"
    sed -i s_'/usr/local/dooble/Lib\x00'_'/opt/dooble/Lib\x00\x00\x00\x00\x00\x00\x00'_g "$pkgdir/opt/dooble/Dooble"
    
    msg "Renaming \$pkgdir/opt/dooble/dooble.sh to \$pkgdir/opt/dooble/dooble"
    mv "$pkgdir/opt/dooble/dooble.sh" "$pkgdir/opt/dooble/dooble"
}