# Maintainer: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>

pkgname=blueshift
pkgver=1.12
pkgrel=1
pkgdesc="An extensible and highly configurable alternative to redshift"
arch=(i686 x86_64)
url="https://github.com/maandree/blueshift"
license=('AGPL3' 'GPL3' 'custom:GFDL1.3')
depends=(python3 argparser libxcb libxxf86vm libx11 libdrm)
optdepends=('adjbacklight: for backlight adjustments without root requirements'
            'linux: for backlight support'
            'wget: for weather support')
makedepends=(cython gcc python3 libxcb libxxf86vm libx11 libdrm make coreutils sed zip texinfo auto-auto-complete)
install=blueshift.install
source=($url/archive/$pkgver.tar.gz)
sha256sums=(cb6ccb2cb2a7f2845f48a85d84f1bbc4effd91942f06489bcce3245965148f60)


build() {
  cd "$srcdir/$pkgname-$pkgver"
  LDFLAGS=${LDFLAGS/--as-needed/}
  LDFLAGS=${LDFLAGS/,,/,}
  export LDFLAGS
  make PREFIX=/usr LIBEXEC=/lib/blueshift
}


package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX=/usr LIBEXEC=/lib/blueshift install DESTDIR="$pkgdir"
}